home *** CD-ROM | disk | FTP | other *** search
/ Cream of the Crop 26 / Cream of the Crop 26.iso / os2 / octa209s.zip / octave-2.09 / libcruft / lapack / zgehrd.f < prev    next >
Text File  |  1996-07-19  |  8KB  |  245 lines
  1.       SUBROUTINE ZGEHRD( N, ILO, IHI, A, LDA, TAU, WORK, LWORK, INFO )
  2. *
  3. *  -- LAPACK routine (version 2.0) --
  4. *     Univ. of Tennessee, Univ. of California Berkeley, NAG Ltd.,
  5. *     Courant Institute, Argonne National Lab, and Rice University
  6. *     September 30, 1994
  7. *
  8. *     .. Scalar Arguments ..
  9.       INTEGER            IHI, ILO, INFO, LDA, LWORK, N
  10. *     ..
  11. *     .. Array Arguments ..
  12.       COMPLEX*16         A( LDA, * ), TAU( * ), WORK( LWORK )
  13. *     ..
  14. *
  15. *  Purpose
  16. *  =======
  17. *
  18. *  ZGEHRD reduces a complex general matrix A to upper Hessenberg form H
  19. *  by a unitary similarity transformation:  Q' * A * Q = H .
  20. *
  21. *  Arguments
  22. *  =========
  23. *
  24. *  N       (input) INTEGER
  25. *          The order of the matrix A.  N >= 0.
  26. *
  27. *  ILO     (input) INTEGER
  28. *  IHI     (input) INTEGER
  29. *          It is assumed that A is already upper triangular in rows
  30. *          and columns 1:ILO-1 and IHI+1:N. ILO and IHI are normally
  31. *          set by a previous call to ZGEBAL; otherwise they should be
  32. *          set to 1 and N respectively. See Further Details.
  33. *          1 <= ILO <= IHI <= N, if N > 0; ILO=1 and IHI=0, if N=0.
  34. *
  35. *  A       (input/output) COMPLEX*16 array, dimension (LDA,N)
  36. *          On entry, the N-by-N general matrix to be reduced.
  37. *          On exit, the upper triangle and the first subdiagonal of A
  38. *          are overwritten with the upper Hessenberg matrix H, and the
  39. *          elements below the first subdiagonal, with the array TAU,
  40. *          represent the unitary matrix Q as a product of elementary
  41. *          reflectors. See Further Details.
  42. *
  43. *  LDA     (input) INTEGER
  44. *          The leading dimension of the array A.  LDA >= max(1,N).
  45. *
  46. *  TAU     (output) COMPLEX*16 array, dimension (N-1)
  47. *          The scalar factors of the elementary reflectors (see Further
  48. *          Details). Elements 1:ILO-1 and IHI:N-1 of TAU are set to
  49. *          zero.
  50. *
  51. *  WORK    (workspace/output) COMPLEX*16 array, dimension (LWORK)
  52. *          On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
  53. *
  54. *  LWORK   (input) INTEGER
  55. *          The length of the array WORK.  LWORK >= max(1,N).
  56. *          For optimum performance LWORK >= N*NB, where NB is the
  57. *          optimal blocksize.
  58. *
  59. *  INFO    (output) INTEGER
  60. *          = 0:  successful exit
  61. *          < 0:  if INFO = -i, the i-th argument had an illegal value.
  62. *
  63. *  Further Details
  64. *  ===============
  65. *
  66. *  The matrix Q is represented as a product of (ihi-ilo) elementary
  67. *  reflectors
  68. *
  69. *     Q = H(ilo) H(ilo+1) . . . H(ihi-1).
  70. *
  71. *  Each H(i) has the form
  72. *
  73. *     H(i) = I - tau * v * v'
  74. *
  75. *  where tau is a complex scalar, and v is a complex vector with
  76. *  v(1:i) = 0, v(i+1) = 1 and v(ihi+1:n) = 0; v(i+2:ihi) is stored on
  77. *  exit in A(i+2:ihi,i), and tau in TAU(i).
  78. *
  79. *  The contents of A are illustrated by the following example, with
  80. *  n = 7, ilo = 2 and ihi = 6:
  81. *
  82. *  on entry,                        on exit,
  83. *
  84. *  ( a   a   a   a   a   a   a )    (  a   a   h   h   h   h   a )
  85. *  (     a   a   a   a   a   a )    (      a   h   h   h   h   a )
  86. *  (     a   a   a   a   a   a )    (      h   h   h   h   h   h )
  87. *  (     a   a   a   a   a   a )    (      v2  h   h   h   h   h )
  88. *  (     a   a   a   a   a   a )    (      v2  v3  h   h   h   h )
  89. *  (     a   a   a   a   a   a )    (      v2  v3  v4  h   h   h )
  90. *  (                         a )    (                          a )
  91. *
  92. *  where a denotes an element of the original matrix A, h denotes a
  93. *  modified element of the upper Hessenberg matrix H, and vi denotes an
  94. *  element of the vector defining H(i).
  95. *
  96. *  =====================================================================
  97. *
  98. *     .. Parameters ..
  99.       INTEGER            NBMAX, LDT
  100.       PARAMETER          ( NBMAX = 64, LDT = NBMAX+1 )
  101.       COMPLEX*16         ZERO, ONE
  102.       PARAMETER          ( ZERO = ( 0.0D+0, 0.0D+0 ),
  103.      $                   ONE = ( 1.0D+0, 0.0D+0 ) )
  104. *     ..
  105. *     .. Local Scalars ..
  106.       INTEGER            I, IB, IINFO, IWS, LDWORK, NB, NBMIN, NH, NX
  107.       COMPLEX*16         EI
  108. *     ..
  109. *     .. Local Arrays ..
  110.       COMPLEX*16         T( LDT, NBMAX )
  111. *     ..
  112. *     .. External Subroutines ..
  113.       EXTERNAL           XERBLA, ZGEHD2, ZGEMM, ZLAHRD, ZLARFB
  114. *     ..
  115. *     .. Intrinsic Functions ..
  116.       INTRINSIC          MAX, MIN
  117. *     ..
  118. *     .. External Functions ..
  119.       INTEGER            ILAENV
  120.       EXTERNAL           ILAENV
  121. *     ..
  122. *     .. Executable Statements ..
  123. *
  124. *     Test the input parameters
  125. *
  126.       INFO = 0
  127.       IF( N.LT.0 ) THEN
  128.          INFO = -1
  129.       ELSE IF( ILO.LT.1 .OR. ILO.GT.MAX( 1, N ) ) THEN
  130.          INFO = -2
  131.       ELSE IF( IHI.LT.MIN( ILO, N ) .OR. IHI.GT.N ) THEN
  132.          INFO = -3
  133.       ELSE IF( LDA.LT.MAX( 1, N ) ) THEN
  134.          INFO = -5
  135.       ELSE IF( LWORK.LT.MAX( 1, N ) ) THEN
  136.          INFO = -8
  137.       END IF
  138.       IF( INFO.NE.0 ) THEN
  139.          CALL XERBLA( 'ZGEHRD', -INFO )
  140.          RETURN
  141.       END IF
  142. *
  143. *     Set elements 1:ILO-1 and IHI:N-1 of TAU to zero
  144. *
  145.       DO 10 I = 1, ILO - 1
  146.          TAU( I ) = ZERO
  147.    10 CONTINUE
  148.       DO 20 I = MAX( 1, IHI ), N - 1
  149.          TAU( I ) = ZERO
  150.    20 CONTINUE
  151. *
  152. *     Quick return if possible
  153. *
  154.       NH = IHI - ILO + 1
  155.       IF( NH.LE.1 ) THEN
  156.          WORK( 1 ) = 1
  157.          RETURN
  158.       END IF
  159. *
  160. *     Determine the block size.
  161. *
  162.       NB = MIN( NBMAX, ILAENV( 1, 'ZGEHRD', ' ', N, ILO, IHI, -1 ) )
  163.       NBMIN = 2
  164.       IWS = 1
  165.       IF( NB.GT.1 .AND. NB.LT.NH ) THEN
  166. *
  167. *        Determine when to cross over from blocked to unblocked code
  168. *        (last block is always handled by unblocked code).
  169. *
  170.          NX = MAX( NB, ILAENV( 3, 'ZGEHRD', ' ', N, ILO, IHI, -1 ) )
  171.          IF( NX.LT.NH ) THEN
  172. *
  173. *           Determine if workspace is large enough for blocked code.
  174. *
  175.             IWS = N*NB
  176.             IF( LWORK.LT.IWS ) THEN
  177. *
  178. *              Not enough workspace to use optimal NB:  determine the
  179. *              minimum value of NB, and reduce NB or force use of
  180. *              unblocked code.
  181. *
  182.                NBMIN = MAX( 2, ILAENV( 2, 'ZGEHRD', ' ', N, ILO, IHI,
  183.      $                 -1 ) )
  184.                IF( LWORK.GE.N*NBMIN ) THEN
  185.                   NB = LWORK / N
  186.                ELSE
  187.                   NB = 1
  188.                END IF
  189.             END IF
  190.          END IF
  191.       END IF
  192.       LDWORK = N
  193. *
  194.       IF( NB.LT.NBMIN .OR. NB.GE.NH ) THEN
  195. *
  196. *        Use unblocked code below
  197. *
  198.          I = ILO
  199. *
  200.       ELSE
  201. *
  202. *        Use blocked code
  203. *
  204.          DO 30 I = ILO, IHI - 1 - NX, NB
  205.             IB = MIN( NB, IHI-I )
  206. *
  207. *           Reduce columns i:i+ib-1 to Hessenberg form, returning the
  208. *           matrices V and T of the block reflector H = I - V*T*V'
  209. *           which performs the reduction, and also the matrix Y = A*V*T
  210. *
  211.             CALL ZLAHRD( IHI, I, IB, A( 1, I ), LDA, TAU( I ), T, LDT,
  212.      $                   WORK, LDWORK )
  213. *
  214. *           Apply the block reflector H to A(1:ihi,i+ib:ihi) from the
  215. *           right, computing  A := A - Y * V'. V(i+ib,ib-1) must be set
  216. *           to 1.
  217. *
  218.             EI = A( I+IB, I+IB-1 )
  219.             A( I+IB, I+IB-1 ) = ONE
  220.             CALL ZGEMM( 'No transpose', 'Conjugate transpose', IHI,
  221.      $                  IHI-I-IB+1, IB, -ONE, WORK, LDWORK,
  222.      $                  A( I+IB, I ), LDA, ONE, A( 1, I+IB ), LDA )
  223.             A( I+IB, I+IB-1 ) = EI
  224. *
  225. *           Apply the block reflector H to A(i+1:ihi,i+ib:n) from the
  226. *           left
  227. *
  228.             CALL ZLARFB( 'Left', 'Conjugate transpose', 'Forward',
  229.      $                   'Columnwise', IHI-I, N-I-IB+1, IB, A( I+1, I ),
  230.      $                   LDA, T, LDT, A( I+1, I+IB ), LDA, WORK,
  231.      $                   LDWORK )
  232.    30    CONTINUE
  233.       END IF
  234. *
  235. *     Use unblocked code to reduce the rest of the matrix
  236. *
  237.       CALL ZGEHD2( N, I, IHI, A, LDA, TAU, WORK, IINFO )
  238.       WORK( 1 ) = IWS
  239. *
  240.       RETURN
  241. *
  242. *     End of ZGEHRD
  243. *
  244.       END
  245.